TempleOSCDV4.08.ISO

This commit is contained in:
Terry A. Davis authored and minexew committed 2018-09-08 21:47:25 +02:00
1 parent b632ab9a4f
commit 2d56cda5f3
258 files changed
+6973 -5476

No files matched your search

+26
View File
@@ -0,0 +1,26 @@
//This makes a file of N random double values.
Cd(__DIR__);;
U0 F64FileGenTXT(U8 *filename,I64 n)
{
I64 i;
CDoc *doc=DocNew(filename);
DocPrint(doc,"//This is unsorted.\n");
for (i=0;i<n;i++)
DocPrint(doc,"%12.6f\n",Rand);
DocWrite(doc);
DocDel(doc);
}
F64FileGenTXT("~/DemoUnsortedF64.TXT.Z",10);
U0 F64FileGenDAT(U8 *filename,I64 n)
{//$LK,"File/CFile",A="HI:File/CFile"$, $LK,"::/Demo/Dsk/DataBase.CPP"$
I64 i;
F64 *a=MAlloc(n*sizeof(F64));
for (i=0;i<n;i++)
a[i]=Rand;
FileWrite(filename,a,n*sizeof(F64));
Free(a);
}
F64FileGenDAT("~/DemoUnsortedF64.DAT.Z",10);
+72
View File
@@ -0,0 +1,72 @@
//This takes an input file of doubles and makes a sorted output file.
Cd(__DIR__);;
I64 Compare(F64 e1,F64 e2)
{
return Sign(e1-e2);
}
U0 F64FileSortTXT(U8 *in_name,U8 *out_name)
{
CCmpCtrl *cc;
I64 i,n;
F64 *a;
CDoc *doc;
//Pass1: Count the number of F64s.
n=0;
cc=CmpCtrlNew(MStrPrint("#include \"%s\"",in_name));
while (Lex(cc))
if (cc->token==TK_F64)
n++;
CmpCtrlDel(cc);
a=MAlloc(n*sizeof(F64));
//Pass2: Read F64s.
i=0;
cc=CmpCtrlNew(MStrPrint("#include \"%s\"",in_name));
while (Lex(cc))
if (cc->token==TK_F64)
a[i++]=cc->cur_f64;
CmpCtrlDel(cc);
QSortI64(a,n,&Compare); //Sort 64-bit sized values
//Save
doc=DocNew(out_name);
DocPrint(doc,"//This is sorted.\n");
for (i=0;i<n;i++)
DocPrint(doc,"%12.6f\n",a[i]);
DocWrite(doc);
DocDel(doc);
Free(a);
}
F64FileSortTXT("~/DemoUnsortedF64.TXT.Z","~/DemoSortedF64.TXT.Z");
Type("~/DemoUnsortedF64.TXT.Z");
Type("~/DemoSortedF64.TXT.Z");
U0 F64FileSortDAT(U8 *in_name,U8 *out_name)
{//$LK,"File/CFile",A="HI:File/CFile"$, $LK,"::/Demo/Dsk/DataBase.CPP"$
I64 size;
F64 *a=FileRead(in_name,&size);
QSortI64(a,size/sizeof(F64),&Compare); //Sort 64-bit sized values
FileWrite(out_name,a,size);
Free(a);
}
F64FileSortDAT("~/DemoUnsortedF64.DAT.Z","~/DemoSortedF64.DAT.Z");
U0 F64FileDumpDAT(U8 *in_name)
{//$LK,"File/CFile",A="HI:File/CFile"$, $LK,"::/Demo/Dsk/DataBase.CPP"$
I64 i,n,size;
F64 *a=FileRead(in_name,&size);
n=size/sizeof(F64);
"%s\n",in_name;
for (i=0;i<n;i++)
"%12.6f\n",a[i];
Free(a);
}
F64FileDumpDAT("~/DemoUnsortedF64.DAT.Z");
F64FileDumpDAT("~/DemoSortedF64.DAT.Z");